:: فــلـنـتـعلـم Avisynth سـويـةً ~

[M-E-M-O]

السلام عليكم ورحمة الله وبركاته

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
------------------
•°.| في هذا الموضوع |.°•
------------------

سيتم شرح اوامر AviSynth اللي تهمكم
طبعا الاوامر كلها موجودة ومشروحه في الملفات اللي تنزل مع البرنامج....
لكن يمكن مع الشرح العربي يزيدون الفاهمين ^^
اللي يلاحظ اي خطأ نرجو أنه يبلغنا....
وأيضا نتطلع إلى أي اضافة منكم لتعم الفائدة ^^


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


الفهرس

أولاً .............::::››› › استيراد الملفات ▌▌ DirectShowSource ▌▌AviSource ▌▌Import

ثانيا ................::::››› › دمج صوت و صورة

ثالثاً ............::::››› › لصق الترجمة

رابعاً ................::::››› › تغيير سرعة الفريمس

خامسا ً........::::››› › تغيير الأبعاد

سادساً ............::::››› › إزالة الهوامش

سابعاً ..........::::››› › إضافة الهوامش

ثامناً................::::››› › عرض بيانات المقطع

تاسعاً ..........::::››› › تغير أنظمة الألوان

عاشراً ..............::::››› › العكس ( القلب )

أحد عشر .....::::››› › لصق الشعار (Logo)

إثنى عشر.........::::››› › شغلات خفيفة على الصوت ▌▌ تغيير التردد ▌▌ التحويل الى Mono ▌▌ التحويل الى Stereo ▌▌ رفع الصوت

ثلاثة عشر....::::››› ›طريقة دمج مقطعين مختلفين تماماً

أربعة عشر.........::::››› › التجزيء و التقطيع

خمسة عشر.::::››› › استيراد صورة كـ فيديو

ستة عشر ........::::››› › التحكم في الإضاءة و التباين و تشبع الألوان

--------------------------
•°.| أولا : أوامر فتح الملفات |.°•
--------------------------

1 - الامر DirectShowSource


هذا الامر نستخدمه لاستيراد معظم ملفات الصوت والصورة...FLv,Mkv,Mp4,Avi,Rm .... الخ
الامر بشكله العام | الاجزاء المهمة فقط

DirectShowSource (string filename, float "fps",bool "audio", bool "video", bool "convertfps")

توضيح المكتوب :
-----------------------------------------
تعني مكان الملف =string filename
سرعة الفريمس = fps .......... هنا القيم true او false .
تشغيل/تعطيل الصوت = audio ...........هنا القيم true او false .
تشغيل/تعطيل الصورة = video ..........هنا القيم true او false
تصحيح الاخطاء في سرعة الفريمس = convertfps ..........هنا القيمtrue او false
-----------------------------------------


لمعرفة سرعة الفريمس : افتح مقطع الفيديو باستخدام Media Player Classic ثم اضغط على الجزء الذي ينعرض فيه الفيديو رايت كلك
ثم Properties>>Details وستجد مربعاً بداخله بيانات حول المقطع من بينها سرعة الفريمس.
--
`عنوان فرعي,

[ مشاكل يسبهها عدم استخدام الرقم الصحيح للفريمس ~

لو ما كتبت الرقم بشكله السليم ،، بحيث الرقم كان خاطيء
بتواجه مشكلة بعد الانتاج بالشكل التالي :-
لو كان المقطع مثلا 22 دقيقة
ستنتهي جميع الفريمات ( الصور خلال ربما دقيقتين )
فهي ستنعرض بسرعة كبيرة جدا
وفي الوقت المتبقي
ستكون الشاشه سوداء وستضل تسمع فقط صوت خلال الوقت المتبقي


------------------------------------------

أمثلة على هذا الأمر
-----------------------------

DirectShowSource("D:\Downloads\Video\sera.mp4",fps=29.97,convertfps=true)

في هذا الامر سيقوم البرنامج بفتح ملف الفيديو D:\Downloads\Video\sera.mp4الذي سرعة الفريمات فيه fps=29.97
وسيقوم البرنامج بتصحيح الاخطاء في سرعة الفريمس إن وجدت .
------------------------------

مثال آخر ..

DirectShowSource("D:\Downloads\Video\sera.mp4",fps=29.97,convertfps=true,video=false)

نفس الامر السابق تقريبا...لكن هنا سيعرض البرنامج الصوت فقط...بدون الصورة لاننا وضعنا video=false


نفس الفكرة اذا اردنا عرض الصورة فقط

DirectShowSource("D:\Downloads\Video\sera.mp4",fps=29.97,convertfps=true,audio=false)

-------------------------------

مثال لفتح الملفات الصوتية ..

DirectShowSource("D:\Downloads\music\liliu.wav")

ملاحظة :- لاتنس علامات التنصيص || "XX" || حول موقع الملف.
ملاحظة 2 :- للحصول على موقع الملف افتح Start>>Run |بالعربي ابدأ>>تشغيل| ... ثم اسحب الملف المراد استخراج مكانة وضعه في منطقه الكتابة في تشغيل Run .

*الامر DirectshowSource يعمل على جميع مقاطع الفيديو التي تعمل على ميديا بلاير كلاسيك
طبعا الميديا بلاير كلاسيك لا يقوم بفتح الملف الا اذا وجد الكوديك المناسب له
على العموم ،، اذا لم يعمل المقطع بسبب نقص في الكوديكس فاتجه إلى هذه الصفحة وستجد الكوديكس المطلوب لكل صيغة

http://avisynth.org/mediawiki/Importing_media


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -

2 - أمر AviSource

هذا الامر يستورد الملفات بصيغة Avi فقط .

----------------------------

الشكل الاكثر استخداما للأمر ..

AVISource (string filename [, ...])

مكان الملف الذي بصيغة string filename[, ...] =Avi

-------------------------------

مثال على الامر ..

AVISource("D:\Downloads\Video\LiarGaemEp.1.avi")

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


3 - أمر Import

هذا الامر يستخدم لاستيراد ملفات Avs فقط
يعني تخيل انك كتبت امراً، اعتبر انه ملف فيديو كامل، عندها ستحتاج إلى هذا الامر لاستيراده.

----------------------------

الشكل العام للامر ..

Import (string filename)

موقع ملف الامر = string filename

--------------------------

مثال على الامر ..

Import ("C:\Documents and Settings\User\Desktop\ac3.avs")

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -




------------------------------------
•°.| ثانياً : أمـر دمج صوت و صورة |.°•
------------------------------------



في هذا الامر نقدر ندمج بين ملف صوت وصورة مستقلين.


-----------------------------

الشكل العام للأمر ..

AudioDub (video_clip, audio_clip)

-----------------------------

مثال على الاستخدام ..

فككت ملف Mkv والان ادمج الصوت و الصورة باستخدام هذا الامر.

video=DirectShowSource("C:\AVISYNTH COURSE\Mkv extract\Track1.avi",fps=23.98,convertfps=true)
audio=DirectShowSource("C:\AVISYNTH COURSE\Mkv extract\Track2.mp3")
AudioDub(video,audio)

---------------------------

في السطر الاول عرفنا المتغير Video بانه استيراد ملف الفيديو C:\AVISYNTH COURSE\Mkv extract\Track1.avi
والسطر الثاني عرفنا المتغير Audio بأنه استيراد لملف الصوت C:\AVISYNTH COURSE\Mkv extract\Track2.mp3

------------------------------------مثال اخر بس عبيط XD

ساستخدم الامر AudioDub على ملف فيديو عادي .. بحيث افككه و اركبه باستخدام الاوامر.

 video=DirectShowSource("D:\Downloads\Video\sera.mp4",fps=29.97,convertfps=true,audio=false)
 audio=DirectShowSource("D:\Downloads\Video\sera.mp4",fps=29.97,convertfps=true,video=false)
audiodub(video,audio)

السطر الاول و الثاني عبارة عن تعريف متغيرات
لو تلاحظون...في الامر DirectShowSource في اول سطر قمت بإلغاء الصوت...وفي السطر الثاني الغيت الصورة ..

ثم دمجت الصوت مع الصورة مرة اخرى :clap:


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -




-----------------------------
•°.| ثالثاً: لصق الترجمة |.°•
-----------------------------


للصق الترجمة سنستخدم VSFilter والامر TextSub | اصلا مشروحة بس زيادة الخير خيرين ^^

================================
يمكنك الحصول على VSFilter من هنا http://sourceforge.net/project/showf...ckage_id=84359
================================

---------------------------------

مثال على كتابة الامر ..

DirectShowSource("D:\Downloads\Video\dr.aqasa.avi",audio=false,fps=29.97,convertfps=true)
LoadPlugin("C:\Program Files\Aegisub\VSFilter.dll")
textsub("C:\Documents and Settings\User\Desktop\avs tests\mytranslation.ass")

زي ماتشوفون...في البداية قمنا باستيراد ملف الفيديو باستخدام الامر DirectShowSource

والسطر الذي يليه قمنا باستدعاء الاداه VSFilter وحددنا مكانه في الجهاز ..

والسطر الثالث استخدمنا الامر textSub لاستيراد ملف الترجمة..وحددنا موقع ملف الترجمة.



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
=============== فاصل إعلاني ==============

ـــ\/ــ\/ ـــ\/ــ\/ـــ\/ــ\/ـــ\/ــ\/ـــ\/ــ\/ــــ\/ــ

قلوبنا معك .. يالأخضر ..

================ عـــدنـــــا ===============
- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



--------------------------------------
•°.| رابعاً : أمر تغيير سرعة الفريمس |.°•
--------------------------------------

الفائدة منه ..

الفايدة من الأمر تغير سرعة الفريمس خصوصا لبعض الملفات اللي سرعتهم 119.88 ....لأنهم يسببون مشاكل أحيانا ><"..

واكبر مشكلة تواجهني هي في برامج التحويل إلى الريل بلاير التي تفتح أوامر AVS ...فهذه البرامج لاتقبل سرعة 119.88

فلذلك نستخدم اوامر تغير سرعة الفريمس

---------------------------------

الأمر بنستخدمه بالشكل التالي ..

Changefps (float new_rate)

وهذا مثال...ملف فيديو سرعة الفريمس 119.88 ونبي نغيرهم باستخدام الاوامر

DirectShowSource("D:\[S^M] Romeo x Juliet 01 RAW.avi",fps=119.88,convertfps=true)
changefps(23.976)

في السطر الأول استخدمنا أمر DirectShowSource لاستيراد الفيديو | لاحظو اني هنا كتبت سرعته نفسها لسه ماغيرت شي
والسطر الثاني غيرنا فيه سرعة الفريمس

معلومة حبيت اضيفها :- سرعة الفريمس 23.9760 هي العدد الحاصل من قسمة 24000 على 1001

ونفس الشيء للسرعة 29.97 هي حاصل قسمة 30000 على 1001


لذلك اذا اردنا كتابة سرعة الفريمس بدقة عالية نكتبها هكذا ..

DirectShowSource("D:\[S^M] Romeo x Juliet 01 RAW.avi",fps=119.88,convertfps=true)
changefps(24000,1001)

------------------------------------

ملاحظة :- تغيرك لسرعة الفريمس يغير من عدد الفريمس
في المقطع اللي عملت عليه المثال كان عدد الفريمس في الاصل 172610
أما بعد تغير سرعة الفريمس فأصبح عددها 34522 ؛
لأن عملية تغير سرعة الفريمس يتم خلالها إما مضاعفة فريمات معينه
أو مسح لبعض الفريمات



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -




-----------------------------
•°.| خامساً : تغيير الأبـعـاد |.°•
-----------------------------


هناك عدة أوامر....سنستخدم BilinearResize

--------------------------------

سنستخدمه بالشكل التالي ..

BilinearResize ( int target_width, int target_height)

العرض = int target_height
الارتفاع = int target_width
لاتغلطون في الترتيب العرض ثم الارتفاع ---------------------------------

مثال....عندي فيديو سأجعل أبعاده 704 × 396

DirectShowSource("D:\Conano.flv",fps=15,convertfps=true)
BilinearResize (704,396)

ملاحظة :- حاول في ترتيبك للأوامر أن تضع أمر تغير سرعة الفريمس| إن احتجت إليه | قبل أمر تغير الابعاد .

ملاحظة 2 :- وأيضا في ترتيب الأوامر ، يفضل وضع أمر لصق الترجمة بعد أمر تغير الابعاد .

ملاحظة 3 :- في برنامج MeGui يجب أن تكون قيمة العرض وقيمة الارتفاع تقبل القسمة على4



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -




-----------------------------
•°.| سادساً : أمـر إزالةالهوامش |.°•
-----------------------------



بعض مقاطع الفيديو يصير فيها هوامش سوداء في الأطراف .. قد تحتاج إلى إزالتها باستخدام هذا الأمر


او تحتاج هذا الأمر لقص الأجزاء السفليه التي عليها ترجمة كما يفعل البعض .

Crop ( int left, int top, int width, int height)

الجزء المقصوص من اليسار =int left
الجزء المقصوص من الأعلى = int top
طول الجزء المعروض بعد الجزء المقصوص من اليسار = int width
طول الجزء المعروض بعد الجزء المقصوص من الاعلى = int height

طبعاً القياسات بالبيكسل.

--------------------------------------
مــثــال ..

لو كان عندي فيديو 400×400 وفيه حدود سوداء طولها 20 بيكسل من جميع الاتجاهات الأربع .

شوفوا شكل الفيديو بالصورة التالية
http://juve11mania.googlepages.com/crop1.gif


و لنقوم بإزالتها نكتب الامر بالشكل التالي ..

AviSource("D:\video\black.avi")
Crop(20,20,360,360)

لاحظوا أنني قمت بقص 20 بيكسل من اليسار والأعلى .. ثم بعدها قمنا بالسماح بعرض 360 بيكسل ..حتى لانعرض السواد الموجود في اليمين والاسفل.

والنتيجة المقطع بدون الهوامش
http://juve11mania.googlepages.com/crop2.gif

على العموم الامر سهل اذا كنت تستخدم Avisynth Editor لكتابة الاوامر
http://juve11mania.googlepages.com/AvisynthEditor.rar


ملاحظة:- اذا كنت تريد تغير الأبعاد أيضاً ، فبالطبع سيكون ترتيب الأوامر .. أمر إزالة الحدود ثم بعدها أمر تغير الأبعاد بالشكل التالي ..

AviSource("D:\video\black.avi")
Crop(20,20,360,360)
BilinearResize (640,480)

لأنك اذا عكستهم بيظهر الهامش .

---------------------------------------

مثال اخر ..

لدي مقطع فيديو ابعاده 704×396 وفيه ترجمة اريد قصها، بحيث اني اريد قص 40 بيكسل من الاسفل

سنكتب الامر بالشكل التالي ..

AviSource("D:\video\pumbep.avi")
Crop(0,0,704,356)

هنا لم أقم بقص أي شيء من اليسار ولا من الأعلى ..

لكني طلبت من البرنامج اظهار 704 بيكسل في العرض ، يعني أظهرت العرض كاملا ..

وطلبت منه اظهار 356 بيكسل ابتداءً من الأعلى ، يعني أن 40 يكسل في الأسفل لن تظهر

وستصبح ابعاد المقطع الجديدة 704×356 .

و نلاحظ أن الطول والعرض يقبلون القسمة على 4 وبالتالي سيعمل المقطع على Megui

وعند لصق الترجمة نضعها بعد أمر القص

AviSource("D:\video\pumbep.avi")
Crop(0,0,704,356)
LoadPlugin("C:\Program Files\Aegisub\VSFilter.dll")
textsub("D:\video\pumbep.ass")

بالشكل هذا يقوم البرنامج بالقص ثم الصاق الترجمة ، وهذا المطلوب ..

اما اذا عكست فسيقوم البرنامج بلصق الترجمة ثم القص ، يعني راحت الترجمة ><"



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
============== فاصل إعلاني : ==============

NoONoO : بوووونكس .. نظافة .. !! ريحة .. !! ........... تفجير .. XD.. !!

================= عــدنــــــــا ================



-----------------------------
•°.| سابعاً : أمــر إضــافـة الـهوامـش |.°•
-----------------------------


هذا عكس الأمر السابق ..

-------------------------------------

الشكل العام للأمر ..

AddBorders ( int left, int top, int right, int bottom, int "color")

الهامش المضاف من اليسار = int left
الهامش المضاف من الاعلى = int top
الهامش المضاف من اليمين = int right
الهامش المضاف من الاسفل = int bottom
لون الهامش ^^ = int "color"

------------------------------------
ملاحظة :- اللون الافتراضي للهامش هو الأسود .. يعني اذا ماحددت اللون بتشوف الهوامش سوداء.
---------------------------------------


مثال على الامر ..

DirectShowSource("D:\Downloads\Video\sola.avi",fps=29.97,convertfps=true)
AddBorders ( 0,0,0,30)

لون الهامش بيكون اسود لأني ماحددت لون
وهذي صورة للأمر عند تشغيله ..
http://juve11mania.googlepages.com/addborder1.gif


وهذا نفس الامر لكن مع تحديد لون ..

DirectShowSource("D:\Downloads\Video\sola.avi",fps=29.97,convertfps=true)
AddBorders ( 0,0,0,30,$C3E56E)

لون الحدود المضافة هنا سيكون زيتي ..
وهذي صورة للأمر عند تشغيله ..
http://juve11mania.googlepages.com/addborder2.gif

على فكرة انا هنا ماحسبت حسابي في الابعاد انها لازم تقبل القسمه على 4
لكن المفروض كل واحد ياخذ حسابه في طول الهامش المضاف ...


أما بالنسبة لـ الألوان تقدرون تجيبونها من الـ Aegisub...لما تختار اللون انسخ الموجود عند HTML
وقم بتغير # بــ $ ....شاهد الصورة
http://juve11mania.googlepages.com/colour.gif


ملاحظة مهمة جداً :- طبعا اذا كنت تريد الصاق الترجمة على مقطع ما قد أضفت

عليه الهوامش ..

فقم بوضع أمر اضافة الهوامش قبل لصق الترجمة ، بالشكل التالي
..

DirectShowSource("D:\Downloads\Video\sola.avi",fps=29.97,convertfps=true)
AddBorders ( 0,0,0,30)
LoadPlugin("C:\Program Files\Aegisub\VSFilter.dll")
textsub("D:\video\rory12.ass")

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



-----------------------------
•°.| ثامناً : أمــر عـرض بـيـانـات الـمـقطـع |.°•
-----------------------------


الأمر هو info


مثال على استخدامه ..

DirectShowSource("D:\Downloads\Video\dr.aqasa.avi")
info()

عند استخدام الامر ستجد البيانات مكتوبة بالاصفر بالشكل التالي..
http://juve11mania.googlepages.com/infoexpaln.gif

طبعا الامر هذا لاتكتبه إلا اذا اردت معرفة بعض البيانات، واذا اردت معرفتها افتح ملف AVS في ميديا بلاير كلاسيك او افتحه في ال VirtualDub....
مالو داعي تسوي انكود علشان تشوف بيانات



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
================== فاصل إعلاني ==================

آي-هايبرا : دكوك مكايو كموناكيز .. ؟

CrEaTiVe : إيش ..
آي-هايبرا : دوقه بالمايونيييز .. !!

CrEaTiVe : إمممم .. لزيييز .. ايش رايك نجربه مع السلكاتكا ..

آي-هايبرا : إييييش ..

CrEaTiVe : نجربه مع السلطططططة .. !!
================ عـــدنـــا ===============
- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



-----------------------------
•°.| تاسعاً : أوامـر تـغـيـر أنـظـمـة الألـوان |.°•
-----------------------------



الأمرين اللذين سنستخدمهما ..

converttoRGB32()

و

converttoYV12()

طريقة استخدام هذين الأمرين مباشرة .. يعني لو كان عندي مقطع نظام الألوان
فيه Rgb32 وأردت تحويله إلى YV12 فسيكون بالشكل التالي ..

DirectShowSource("C:\AVISYNTH COURSE\Mkv extract\Track1.avi",fps=23.98,convertfps=true)
converttoYV12()

و بكذا صار YV12

----------------------------------

وافترض ان لدينا مقطع RGB32 لو قمت بكتابة الأمر بالشكل التالي ..

DirectShowSource("C:\AVISYNTH COURSE\Mkv extract\Track1.avi",fps=23.98,convertfps=true)
converttoYV12()
converttoRGB32()

فإن نظام الألوان في النهاية سيكون RGB32 .. | .. يعني حول نظام الالوان الى YV12 ثم ارجع مرة أخرى وحولها إلى RGB32 والنتيجة صفر ^^

-------------------------------------

على كل حال أعتقد أن هذا الأمر سبق وشاهدتوه في Megui لأنه يفرض عليك التحويل إلى YV12

-------------------------------------

لكن سؤال بسيط ماهو الفرق بين RGB32 و YV12 ؟

في RGB تتكون الصورة من خلط الألوان الاحمر والاخضر والازرق

أما في YV12 فالصورة تتكون من صورة أساس تحدد اضاءة الصورة , وصورة الاساس تكون

بالأبيض والأسود ..

وفوق صورة الاساس تتكون الصورة من خلط الأحمر والازرق ..

الصورة في YV12 اقرب إلى الواقعية من RGB32 <<-- سيتم شرحها مفصلةً في الشرح القادم بإذن الله ..

شوفوا هذي صور من ويكيبيديا ^^

=======================
هذي الصورة لطريقة التكوين في RGB
http://juve11mania.googlepages.com/B...separation.jpg
=======================

=======================
أما هذي لطريقة التكوين في YV12
http://juve11mania.googlepages.com/200px-Barn-yuv.png
=======================


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



-----------------------------
•°.| عاشراً : أوامـرالعكس ( القلب) |.°•
-----------------------------



الامران هما ..

 FlipHorizontal()

و

FlipVertical()

للعكس أفقياً = FlipHorizontal
للعكس رأسياً = FlipVertical

-----------------------------------

اعتقد الفايدة الوحيدة المعروفه هي العكس من اجل إلصاق الكاروكي العربي ، وفيه سيكون الأمر بالشكل التالي ..

DirectShowSource("C:\Documents and Settings\User\My Documents\[S^M] Detective Conan 468 RAW.wmv",fps=23.97,convertfps=true)
LoadPlugin("C:\AVISYNTH COURSE\VSFilter.dll")
fliphorizontal()
TextSub("C:\AVISYNTH COURSE\c22arabic.ass")
fliphorizontal()

السطر الأول :-
استيراد ملف الفيديو .

السطر الثاني :-
استدعاء الاداة VSFilter

السطر الثالث :-
العكس أفقياً .

السطر الرابع :-
إلصاق ملف الكاروكي .

السطر الخامس :-
تعديل الملف بعكسه مرة اخرى .



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
================== فاصل إعلاني ================

تتا تتا تتا رارا .. تتا تتا تتا رارا ..
<<<---- كرييتف و فانتوم يطامرون .. 498
هيد آند شولدرز .. الصحة فشعرك XD

================== عـــدنــــــــا =================
- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



-----------------------------
•°.| أحد عشر: لصق الشعار Logo |.°•
-----------------------------



بشرح الطريقة باستخدام الفلتر Logo1.7 اللي يطلع مع VirtualDub

اللي ماعنده الفلتر يحمله من هنا http://juve11mania.googlepages.com/Logo.vdf

ملاحظة مهمة جداً :- إن فلتر Logo يشتغل على نظام الوان RGB32 فقط.

------------------------------------

سأضع المثال مباشرة واشرح عليه ..

DirectShowSource("C:\AVISYNTH COURSE\Raw Doraemon.avi",fps=23.97,convertfps=true)
LoadVirtualDubPlugin("C:\Documents and Settings\User\Desktop\logo17b2\Logo.vdf","logo")
converttorgb32()
Logo(165, 9, 255, 0, 0, 0, 255, 0, "C:\\AVISYNTH COURSE\\g1.bmp", 0, 1505, 32, 0, 0, 0, 0)
converttoyv12()

السطر الاول :-
استدعاء ملف الفيديو .

السطر الثاني :-
استدعاء للفلتر Logo1.7 ...كما تلاحظون استخدمنا الأمر LoadVirtualDubPlugin للإستدعاء

, و داخل أمر الاستدعاء نقوم بتحديد موقع الفلتر | لانتسو علامة التنصيص " " | وبعد

موقع الفلتر نقوم بتعريف متغير يكون بين علامتي تنصيص "" وأنا هنا سميت المتغير بـ Logo

السطر الثالث :-
قمنا بتحويل نظام الالوان إلى RGB32 لان الفلتر لايعمل على YV12

السطر الرابع :-
هو الذي نضبط فيه اعدادات الشعار .. في البداية قمنا بوضع المتغير Logo ثم الاعدادات داخل القوسين .

---------------------------------------

بالنسبة للاعدادات فلا تقلق .. لن تكتب الاعدادات بنفسك، اتبع الطريقة التالية وسترتاح

افتح برنامج الـ VirtualDub أو VirtualDub Mod

ثم روح وافتح الفيديو حقك ، ثم من قائمة الفلاتر اضف فلتر ( logo 1.7b2 ) واضبط اعدادته بما يناسبك ..

الآن اضغط File>>Save Processing Settings ...وقم بحفظ ملف ضبط الاعدادات

قم الان قم بفتح ملف ضبط الاعدادات الذي حفظته للتو باستخدام الدفتر او المفكرة وسترى مثل هذا ..

VirtualDub.audio.SetSource(1);
VirtualDub.audio.SetMode(0);
VirtualDub.audio.SetInterleave(1,500,1,0,0);
VirtualDub.audio.SetClipMode(1,1);
VirtualDub.audio.SetConversion(0,0,0,0,0);
VirtualDub.audio.SetVolume();
VirtualDub.audio.SetCompression();
VirtualDub.audio.EnableFilterGraph(0);
VirtualDub.video.SetInputFormat(0);
VirtualDub.video.SetOutputFormat(7);
VirtualDub.video.SetMode(3);
VirtualDub.video.SetFrameRate(0,1);
VirtualDub.video.SetIVTC(0,0,-1,0);
VirtualDub.video.SetCompression();
VirtualDub.video.filters.Clear();
VirtualDub.video.filters.Add("logo (1.7b2)");
VirtualDub.video.filters.instance[0].Config(164, 10, 255, 0, 0, 0, 255, 0, "C:\\AVISYNTH COURSE\\g1.bmp", 0, 1505, 32, 0, 0, 0, 0);
VirtualDub.audio.filters.Clear();

الشيء الوحيد المطلوب هو مابين هذين القوسين

(164, 10, 255, 0, 0, 0, 255, 0, "C:\\AVISYNTH COURSE\\g1.bmp", 0, 1505, 32, 0, 0, 0, 0)

انسخه وضعه بجوار المتغير Logo كما قمت أنا بذلك

أما السطر الخامس فهو لإرجاع نظام الالوان إلى YV12

ملاحظة :- تستطيع استخدام الفلتر Region Remove بنفس الاسلوب .

ملاحظة2 :- اذا كان لديك أكثر من ملف شعار فعندما تفتح ملف ضبط الاعدادات ستجد سطرين

يحتويان على الأقواس وستكتب الأمر بنفس الشكل هكذا ..

( سميت المتغير هذه المرة بـ mo بدلا من Logo )

DirectShowSource("C:\Documents and Settings\User\My Documents\[S^M] Bleach 121 RAW.avi",fps=23.97,convertfps=true)
LoadVirtualDubPlugin("C:\Documents and Settings\User\Desktop\logo17b2\Logo.vdf","mo")
converttorgb32()
mo(0, 0, 255, 2, 0, 0, 255, 0, "C:\\AVISYNTH COURSE\\MSOMS-ANIME_S\\MSOMS-ANIME\\MSOMS-Anime-0000.bmp", 1, 0, 1, 1, 0, 0, 0)
mo(312, 232, 255, 2, 0, 0, 255, 0, "C:\\AVISYNTH COURSE\\MSOMS-ANIME_S\\wait.bmp", 0, 0, 0, 0, 0, 0, 0)
converttoyv12()

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


-----------------------------------------
•°.| إثني عشر : شغلات خفيفة على الصوت |.°•
-----------------------------------------



مبدئياً .. الأوامر هذي تحتاجهم فقط في دمج مقطعين ، ومسألة الدمج سنوضحها لاحقا ..


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


1 - لتغيير التردد نستخدم الأمر ResampleAudio

ResampleAudio (int new_rate_numerator)

التردد الجديد = int new_rate_numerator

--------------------------------------------

مثال سريع ..

DirectShowSource("C:\Documents and Settings\User\Desktop\251.rv",fps=15)
ResampleAudio(48000)

جعلنا التردد 48000


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


2 - للتحويل إلى Mono نستخدم الأمر ConvertToMono

ConvertToMono ()

-------------------------------------------

مثال ..

DirectShowSource("C:\Documents and Settings\User\Desktop\475.avi",fps=23.976)
ConvertToMono ()

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


3 - التحويل إلى Stereo

سنحتاج إلى الأمر MonoToStereo للتحويل الى stereo ،طريقة استخدامه فيها تعريف متغيرات وسنحتاج إلى الأمر AudioDub
سأضع لكم هذا المثال مباشرة وطبقوا عليه..

video=DirectShowSource("C:\Documents and Settings\User\Desktop\251.rv",fps=15)
audio=MonoToStereo(video,video)
audiodub(video,audio)

السطر الاول :-
تعريف للمتغير video
السطر الثاني :-
تعريف للمتغير Audio ....... والمتغير Audio هنا عبارة عن أمر خلط الاصوات الموجودة في Video لتكوين صوت Stereo
السطر الثالث :-
خلط الصوت بالصورة
اللي ما فهم لا يتعب نفسه ينسخ الامر ويغير موقع ملف الفيديو فقط

------------------- فاصل لقافة -----------------

Uchiha.Haibra : وش الفرق بين الـ Mono والستيريو ؟

CrEaTiVe : يا عمي طلعوا ذا الولد برا الفصل
knary : يا ملقوف يا كرييتف .. إطلع برا .. ولا أشوف خشتك هنا ..

يوتشي يا حبيبي .. ما عليك من كرييتف التحشيش مأثر عليه ..
..
في Mono يتكون الصوت من قناة واحدة
اما Stereo يتكون من قناتين واحدة يمنى والأخرى يسرى

-----------------عــدنــا-----------------

4 - رفع الصوت

طبعاً البعض يشتكي من ان المقطع صوته ضعيف
نستخدم الأمر Normalize لزيادة الصوت

AVISource("D:\Downloads\Video\[Detective Conan][476][RAW].avi")
Normalize(.97)

الرقم 0.97 يعني نسبة التعديل بتكون 97%
انتو جربوا الارقام وشوفوا المناسب لكم




- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
---------------------------------------------------
•°.| ثلاثة عشر : طريقة دمج مقطعين مختلفين تماماً |.°•
---------------------------------------------------



طبعاً للقيام بذلك يجب أن يكون المقطعين متشابهين ..

والتشابه يكون في سرعة الفريمس ، ابعاد الصورة، نظام الالوان، تردد الصوت....إلخ

لذلك سنعمل 3 ملفات أوامر ، شوفوا معاي كيف ^^

-------------------------------------------

هذا الملف الاول ، وهذا مكانه C:\awal.avs

AVISource("D:\Downloads\Video\[Detective Conan][476][RAW].avi")
changefps(23.976)
BilinearResize(640,480)
converttoyv12()
ConvertToMono()
ResampleAudio(48000)

---------------------------------------

وهذا الملف الثاني ، وهذا مكانه C:\thqni.avs

DirectShowSource("C:\mytest\251.rv",fps=15)
changefps(23.976)
BilinearResize(640,480)
converttoyv12()
ConvertToMono ()
ResampleAudio(48000)

طبعاً بنظرة بسيطه انا قاعد أحاول اخلي مواصفات الملفين متشابهة ، وقاعد اكتب نفس الأوامر للملفين.

السطر الاول :-
لاستدعاء المقطع .

السطر الثاني :-
كتبنا امر تغير سرعة الفريمس ، علشان اخلي السرعة في المقطعين متشابهة.

السطر الثالث :-
كتبت الابعاد اللي ابيهم.

السطر الرابع :-
نظام الالوان اللي ابيه.

السطر الخامس :-
تحويل الى Mono
ملاحظة :- قد لا تحتاج اليه اذا كان المقطعين كليهما Stereo
لكن اذا كانو مختلفين استخدمه أو قم بتحويل المقطع الذي فيه الصوت Mono الى Stereo
المهم هو ان يتشابه المقطعين.

والسطر الاخير :-
لضبط التردد.

--------------------------------------

الان نأتي ونصنع ملفا ثالثا، نكتب فيه التالي ..

a=import("C:\awal.avs")
b=import("C:\thqni.avs")
a+b

السطر الاول :-
تعريف متغير .
ملاحظة :- استخدمنا الأمر Import لاستيراد ملف AVS

والسطر الثاني :-
أيضاً تعريف متغير بنفس الأسلوب
السطر الثالث هو سطر الدمج، للدمج نستخدم (+)

لذلك جرب واحفظ الأمر الثالث، لما تشغله بتحصل المقطعين الأول والثاني تم دمجهم.


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
================= فاصل إعلاني =================

CrEaTiVe : مافي دانااااو 9
Uchiha_Sasuke : مافي داناااااو 9
Phantom Kid : مافي داناااااااااااااو 9
M-E-M-O : مافي داناااااااااااااااااااااا اااااااااااااااااو 9
<<--- الحين يدورون حول الطاولة ..

================= عـــدنـــا ===============
- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -

----------------------------------------------------
•°.| أربعة عشر : التجزيء و التقطيع ( مجزرة XD ) |.°•
----------------------------------------------------



الشغل هنا كله بيكون على الأمر Trim للتجزيء .. بالاضافة الى أننا سنستخدم إشارة (+) للدمج.

--------------------------------------------

شكل الامر Trim كذا ..

Trim ( int first_frame, int last_frame)

ببساطه ..
رقم اول فريم يراد عرضه = int first_frame

رقم آخر فريم يراد الانتهاء من العرض عنده = int last_frame

زي ماتشوفون الأمر يعتمد على أرقام الفريمس ومواضعها لذلك لاتنسون هذي العبارة ..

ملاحظة :- تغيرك لسرعة الفريمس يغير من عدد الفريمس .. .. .. في المقطع اللي عملت عليه المثال كان عدد الفريمس في الاصل 172610
أما بعد تغير سرعة الفريمس فأصبح عددها 34522

يعني تغيرت اماكنهم ^^


بالنسبة لارقام الفريمس من وين نجيبها
اما من خلال فتح الملف في الفيرشال داب ..
أو من خلال كتابة الأمر info في ملف ال avs وعرضه ،، ثم معرفة الارقام من خلال العرض


------------------------------------------

طيب نشوف الأمثلة ..

هذي واحده من حلقات كونان 0 .. أريد ضغطها بدون أغنية البداية والنهاية مع إلصاق الترجمة عليها ..

وملف الترجمة تم توقيته في الـAegisub على أساس وجود الأغنيتين..

لنفترض ان بداية الحلقه عند الفريم 3000 ونهايتها عند 31000

نكتب الامر بالشكل التالي ..

DirectShowSource("C:\Documents and Settings\User\My Documents\[S^M] Detective Conan 468 RAW.wmv",fps=23.97,convertfps=true)
LoadPlugin("C:\AVISYNTH COURSE\VSFilter.dll")
TextSub("C:\testoo.ass")
trim(3000,31000)

و بكذا نعرض الجزء المحدد بين 3000 و 31000 فقط
وأيضا لاحظوا أنني ألصقت الترجمة قبل القص بسبب التوقيت سابقا.

-------------------------------------------

مثال اخر ..

لدي حلقة من بليتش .. يوجد فيها إعلان يبدأ عند الفريم 2296 وينتهي عند 3740 .. المقطع كان فيه 40044 فريم

لإزالة الاعلان نقوم بالتالي ..

DirectShowSource("C:\Documents and Settings\User\My Documents\[S^M] Bleach 121 RAW.avi",fps=23.97,convertfps=true)
Trim(0,2296)+Trim(3740,40044)

CrEaTiVe : تعال تعال تعال .. إيش هذا اللي مكتوب فوق ..

M-E-M-O : هذا يا طويل العمــ ...

طرااااااخ ..

M-E-M-O : أيييي ,, آآآسف و الله ما أتكلم مره ثانية ..

knary : أستغفر الله .. فصل يجيب الهم .. كله لقافه ..المهم .. 1 " class="inlineimg" />

معنى اللي كتبناه يا كرييتف و يا ميمو ..

اعرض المقطع ابتداءً من الفريم رقم 0 وحتى 2296 ثم من 3740 وحتى 40044

أو يمكن الاستفادة من خاصية اخرى لإزالة الاعلان ، وذلك بكتابة الامر بالشكل التالي ..

DirectShowSource("C:\Documents and Settings\User\My Documents\[S^M] Bleach 121 RAW.avi",fps=23.97,convertfps=true)
Trim(3740,2296)

M-E-M-O : ممكن أشرحه يا أستاذ .. ؟

knary : طبعاً .. لأ ..

M-E-M-O :

knary : معنى الأمر لا تعرض الجزء الموجود بين الفريم 2296 و 3740
انا هنا قمت بعكس ترتيب الفريمس (3740 جاءت قبل2296 ) ، فيفسرها البرنامج بعدم عرض هذا الجزء .



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
----------------------------------------------
•°.| خمسة عشر : أمر استيراد صورة كفيديو |.°•
----------------------------------------------



الأمر المستخدم ImageSource

ImageSource (string "file", float "fps")

موقع الصورة = string "file"
سرعة الفريمس التي ستعرض بها الصورة = float "fps"

--------------------------------

مثال ..

imagesource("C:\Documents and Settings\User\My Documents\03.jpg",fps=15)

ملاحظة :- اذا احتجت إلى ان تضع صورة ثابته قبل الفيديو تكون مدتها مثلا 5 ثواني فأنت ستستخدم

طريقة الدمج المشروحه في ( ثلاثة عشر ) ..

لكن انتبه إلى انه عند الدمج يجب أن يحتوي كلا المقطعين على صوت ..

لذلك يجب أن نضيف صوتاً (صامتاً) إلى الأمر الذي يحتوي على الصورة

وبالتالي سيكون شكل ملف الأوامر المستخدمة لفتح الصورة هكذا ..

Video=imagesource("C:\Documents and Settings\User\My Documents\ArrowBrushes\03.jpg",fps=15)
audio=BlankClip(audio_rate=48000)
AudioDub(video,audio)
changefps(23.976)
BilinearResize(640,480)
converttoyv12()

ِ



إستخدمنا ..

 Audio=BlankClip(audio_rate=48000)

لإضافة صوت صامت تردده 48000



- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -
================ فاصل إعلاني ================

Phantom Kid : أنـــقــذنــي يـا حــلــيــب الــســعــوديــة

================= عـــدنـــا ===============
- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -



----------------------------------------------
•°.| ستة عشر : التحكم في الاضاءة والتباين و تشبع الالوان |.°•
----------------------------------------------



التحكم يكون باستخدام Tweak وهذي محتويات الامر (فقط الاجزاء المهمة)

Tweak( [, float sat] [, float bright] [, float cont]  )

تشبع الالوان = sat
الاضاءة = bright ...... مناسبة اذا كان الفيديو مظلم جدا
التباين = cont

---------------------------------------

قيمة sat الافتراضية 1.. وهي تأخذ القيم من 0 وحتى 10

بحيث انه في صفر تكون الصورةأبيض واسود .. واقل من واحد تنقص التشبع ، أما أكثر فيزيد التشبع

أما bright فقيمتها الاساسية (صفر) وتاخذا القيم من -255 وحتى 255

في القيم الموجبه تزيد الاضاءة ، اما السالبة تقلل الاضاءة

أما في Cont فقيمتها الاساسية 1 وتاخذ القيم من 0 وحتى 10

----------------------------------------------

هذا مثال ، فيديو قمت بزيادة الاضاءة فيه ..

AVISource("C:\Documents and Settings\User\Desktop\1.avi")
Tweak(bright=10)

نفس الفيديو قمت بزيادة الاضاءة والتباين ..

AVISource("C:\Documents and Settings\User\Desktop\1.avi")
Tweak(cont=1.1,bright=20)

على نفس الفيديو قمت ايضاً بزيادة تشبع الالوان

AVISource("C:\Documents and Settings\User\Desktop\1.avi")
Tweak(sat=1.3,cont=1.1,bright=20)

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -


و الحمدلله رب العالمين ..


قام بهذا العمل :-

الشرح :- knary

التنسيق و الإعداد :- M-E-M-O

التدقيق :- CrEaTiVe

إضافات بسيطة ع الشرح :- CrEaTiVe & M-E-M-O


آملين أن يحوز الشرح على رضاكم .. <<--- مسوي رسمي .. XD


- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -

إخوانكم .. بعضهم في فضاء الإبداع وبعضهم في الطريق .. 0

knary .. CrEaTiVe .. M-E-M-O

اللي عنده أي استفسار أو إضافة ،، فحنا نرحب فيه ونتمنى أنه يكتبها ونضيفها في هذا الموضوع بحيث يكون الموضوع مرجع لمن اراد الاستفادة ^^